Value2 Variable Not Defined - arrays

Question

I have converted a range to an array and then I want to loop through each value to count how many no empty values there are.
For some reason this was working fine
Option Explicit
Sub ArrayCount ()
Dim cmArray As Variant
Set cmArray = Worksheets("Sheet1").Range("H19:CN19")
ColCount = 1
For Each Value2 in cmArray
If Value2 <> "" Then
ColCount = ColCount + 1
End If
Next
End Sub
It all seemed simple enough to me and worked well. Now all of a sudden I am getting an error saying "Compile Error: Variable not defined" and it is highlighting Value2. Is anyone able to explain what is happening here or talk me through what may have happened?
Thanks in advance

Answer 1

It looks like you're trying to put the Value property of a Range object in an array and loop through that array. That's not what you're doing and there are a few concepts at play here.
Default Properties
When you reference an object and don't specify a property, you are actually accessing its default property. For most objects, if it has a Value property, that's the default. And if it has an Item property, that's the default. The Range object is a little weird. Most times the Value property is the default property of a Range. In some cases, the Cells property is the default. If you say
vValue = rMyRange
You are setting vValue equal to the Value property. Make it a habit to always include a property rather than rely on the default.
vValue = rMyRange.Value
The Set Keyword
The Set keyword stinks. But because of default properties, it is necessary. When you use Set, you're saying you want an object variable to point to an object. If you don't use Set, you're saying you want a data variable to be equal to a value.
vValue = rMyRange 'vValue = rMyRange.Value
Set vValue = rMyRange 'vValue points to the range object
vValue = rMyRange.Value 'same as the first, good programming practice
Set vValue = rMyRange.Value 'you get an error - a good reason to specify property
Variants
Excel has a Variant data type that can be cast into any of the normal data types. This is because Excel cells can hold a lot of different types of data and they needed something with similar flexibility. If you want to read the value of a cell and can't be sure what will be in it, use a Variant. There are a few other times to use a Variant (like reading a range into an array). In general, don't use a Variant unless you have a very specific (and good) reason to.
Arrays from Cells
If you assign the Value or Value2 property of a Range to a Variant variable, and the Range has more than one cell, the variable will be cast as a two-dimensional array. It's the most awesome way to read Excel data and work with it - speed wise. But you have to start with a Variant so you have to be extra careful about the above concepts.
vVariant = rRange.Value 'creates an array in vVariant
Set vVariant = rRange.Value 'causes an error
Set vVariant = rRange 'vVariant gets cast to a Range object - not what you wanted
So use the first syntax. Then you can use For i = LBound(vVariant,1) to UBound(vVariant,1) to loop through. Or you can use For Each vItm in vVariant.
Worksheet Function Way
Sub ArrayCount()
Dim rRow As Range
Dim lColCnt As Long
Set rRow = Sheet1.Range("H19:CN19")
lColCnt = Application.WorksheetFunction.CountA(rRow)
Debug.Print lColCnt
End Sub
Array Way
Sub ArrayCntArray()
Dim cmArray As Variant
Dim i As Long
Dim lColCnt As Long
cmArray = Sheet1.Range("H19:CN19").Value
For i = LBound(cmArray, 2) To UBound(cmArray, 2)
If Len(cmArray(1, i)) > 0 Then
lColCnt = lColCnt + 1
End If
Next i
Debug.Print lColCnt
End Sub
Range Object Way
Sub ArrayCountRange()
Dim rRow As Range
Dim rCell As Range
Dim lColCnt As Long
Set rRow = Sheet1.Range("H19:CN19")
For Each rCell In rRow.Cells
If Len(rCell.Value2) > 0 Then
lColCnt = lColCnt + 1
End If
Next rCell
Debug.Print lColCnt
End Sub

Answer 2

You are using Option Explicit, which means all variables should be dimensioned. Simply adding Dim Value2 as Variant at the dimension area should be enough.
Option Explicit
Sub ArrayCount ()
Dim cmArray As Variant
Dim Value2 As Variant
'Code follows...
As a side note, Value2, while I don't know if it's a reserved keyword, is a property. Try changing it to something else as well to be safe or to avoid confusion.
Hope this helps.