Editing file with a batch file - batch-file

Question

I have a small script to edit text in a .conf file.
SETLOCAL=ENABLEDELAYEDEXPANSION
rename c:\users\administrator\desktop\httpd.conf text.tmp
for /f %%a in (text.tmp) do (
set foo=%%a
if !foo!=="### Section 3: Virtual Hosts" set foo="SSL Compression off"
echo !foo! >> c:\users\administrator\desktop\httpd.conf)
del text.tmp
It doesn't have the desired effect as it seems to delete quiet a lot of data from the file. Is there an alternative way I can do this?
I just need to replace ### Section 3: Virtual Hosts with SSL Compression off, whilst maintaining the integrity of the file. The current script seems to delete spaces also :(
Many thanks

Answer 1

Try this:
#echo off
setlocal
call :FindReplace "### Section 3: Virtual Hosts" "SSL Compression off" httpd.conf
exit /b
:FindReplace <findstr> <replstr> <file>
set tmp="%temp%\tmp.txt"
If not exist %temp%\_.vbs call :MakeReplace
for /f "tokens=*" %%a in ('dir "%3" /s /b /a-d /on') do (
for /f "usebackq" %%b in (`Findstr /mic:"%~1" "%%a"`) do (
echo(&Echo Replacing "%~1" with "%~2" in file %%~nxa
<%%a cscript //nologo %temp%\_.vbs "%~1" "%~2">%tmp%
if exist %tmp% move /Y %tmp% "%%~dpnxa">nul
)
)
del %temp%\_.vbs
exit /b
:MakeReplace
>%temp%\_.vbs echo with Wscript
>>%temp%\_.vbs echo set args=.arguments
>>%temp%\_.vbs echo .StdOut.Write _
>>%temp%\_.vbs echo Replace(.StdIn.ReadAll,args(0),args(1),1,-1,1)
>>%temp%\_.vbs echo end with

Answer 2

#ECHO OFF
SETLOCAL
SET originalpath=.
SET originalname=%originalpath%\q20189766.txt
rename %originalname% text.tmp
(for /f "delims=" %%a in (%originalpath%\text.tmp) do (
if "%%a"=="### Section 3: Virtual Hosts" (ECHO(SSL Compression OFF
) ELSE (ECHO(%%a)
)
) >%originalname%
del %originalpath%\text.tmp
GOTO :EOF
I've replaced your pathname and filename with names to suit my system. You would need to replace the values assigned to originalpath and originalname to suit your system.
Note that ECHO( is deliberate - the ( in this character-sequence does NOT affect statement-grouping.

Answer 3

This uses a helper batch file called repl.bat from - https://www.dropbox.com/s/qidqwztmetbvklt/repl.bat
Place repl.bat in the same folder as the batch file or in a folder that is on the path.
The search term is a regular expression but your term should work ok.
#echo off
type text.tmp | repl "### Section 3: Virtual Hosts" "SSL Compression off" > c:\users\administrator\desktop\httpd.conf