Batch file, loop on folder seems to freeze - batch-file

Question

I need to delete with a batch a list of directories (and subdir) which name starts with a number.
My tree is something like that:
|- root
|--event=aaa
|--photo
|--123
|--44
|--23
|--89
|--otherdir
|--event=bbb
|--photo
|--432
|--67
|--12
|--32
|--otherdir
I found this working example: http://www.dostips.com/forum/viewtopic.php?f=3&t=1496
And this is what I wrote
#ECHO OFF
SET path=\\mypath
SET dir=\parentDir\
:: loop on event=* folders
FOR /D /R %path%%dir% %%K IN ("*event*") DO (
:: if an event contains photos ..
IF EXIST %%K\photo (
ECHO %%K
:: loop on dir inside photo folder with a numeric name
PUSHD %%K\photo ||goto :eof
FOR /f "delims=" %%a IN ('dir /ad /b /s ^|findstr /rc:"\\[0-9]"') DO (
IF EXIST %%~a (
RD /s /q "%%~a"
)
)
POPD
) ELSE (
ECHO.%%K /photo does not exists
)
)
ECHO.completed
PAUSE
the only problem I found is that the execution seems to freeze when the last /event=xxx folder, and takes quite a long time to ECHO the last line ("completed"). I don't understand why .. any ideas?
Many thanks

Answer 1

You can try this. It will delete every folder under the *event* folders that have only numbers in the names.
Currently it will pause on each main folder after merely listing the set of subdirectories that would be deleted, and is not destructive. If the commands look right then remove the echo and the pause to activate the RD command to actually delete the folders.
#echo off
for /f "delims=" %%a in (' dir "*event*" /ad /b ') do (
for /f "delims=" %%b in (' dir "%%a" /ad /b /s ') do (
for /f "delims=0123456789" %%c in ("A%%~nxb") do (
if "%%c"=="A" if exist "%%b\" echo rd /s/q "%%b"
)
)
pause
)

Answer 2

#ECHO OFF
SETLOCAL
SET mypath=.
SET dir=\parentdir\
FOR /f "delims=" %%i IN (
' dir /ad /s /b "%mypath%%dir%" ^|findstr /r "\\.*event.*\\photo\\[0-9].*" ' ) DO (
IF EXIST "%%i" ECHO RD /s /q %%i
)
This should do as you ask - with some cautions.
I've changed the variable names. PATH is not a good name to use because PATH is the sequence of directories which the OS searches for an executable.
I've also changed the value to suit my system.
I've added an ECHO keyword rather than arbitrarily deleting the target directories - just in case of a typo - gives you a chance at verifying first. This ECHO would need to be removed to activate the delete functionality.
The findstr regular expression is \ (which requires an extra \ as an escape) any number of any characters, event, any number of any characters, \photo\, a digit then any number of any characters.
Please also note that the "broken label" form of comment (::) should not be used within a loop. Whereas it (and labels) works within a loop in W7 (and presumably later,) it terminates the loop in some earlier Windows editions, whereas REM works for all editions.