Batch files: ask for user input with "suggestions" - batch-file

Question

How can I prompt users for an answer, suggesting something they can edit?
I know how to make a q&a like:
1. The sky is:
The user put the answer and:
echo For you the sky is %var%
But i want something like:
1. The sky is: Blue
echo For you the sky is Blue
But the user can change it
1. The sky is: Green
echo For you the sky is Green
I don't know if i was clear, tell me if not.
Thanks

Answer 1

Initialize the variable before with a color:
#echo off&setlocal
set "color=Blue"
set/p "color=For you the sky is %color% (hit enter for o.k. or type in other color): "
echo For you the sky is %color%

Answer 2

You can use WScript.Shell's SendKeys method through JScript or VBScript to simulate keypresses. Give this a shot. I think it does what you're looking for. It will send uneditable 1. The sky is: then simulate the user keystrokes of Blue. The user is then free either just to hit Enter, or he can Backspace to erase "Blue" and replace it whatever he wishes.
Save this with a .bat extension and run it.
#if (#a==#b) #end /*
:: batch portion
#echo off
setlocal
set /p "=1. The sky is: "<NUL
call :sendkeys Blue
set /p "sky="
echo For you the sky is %sky%. Press any key to exit.
pause >NUL
exit /b
:sendkeys <string>
cscript /nologo /e:jscript "%~f0" "%~1"
goto :EOF
:: JScript portion */
var sh = new ActiveXObject("WScript.Shell");
sh.SendKeys(WSH.Arguments(0));

Answer 3

set x=blue
set y=
set /p "y=The sky is [%x%] "
if not defined y set y=%x%
echo For your the sky is %y%
If user input is empty, the predefined %x% is copied to the outputvariable %y%

Answer 4

As other answers said, you must need a third party utility to solve this problem. For example, I used my GetKey.exe and Show.exe auxiliary programs to write ReadLine.bat, a subroutine that simulate SET /P command, that is, it read characters until Enter key is pressed and delete the last character with BackSpace key. We may modify such routine in order to provide an initial value for the input variable:
#echo off
rem Read a variable with an initialized value
rem Antonio Perez Ayala
set Bell=7
set BackSpace=8
set Enter=13
set Space=32
:ReadInitVar var="prompt" ["initial value"]
rem %1 %2 %3
setlocal EnableDelayedExpansion
Show %2
set len=0
if "%~3" equ "" (
set %1=
) else (
Show %3
set "%1=%~3"
for /L %%i in (0,1,80) do if "!%1:~%%i,1!" neq "" set /A len+=1
)
:nextKey
GetKey
set key=%errorlevel%
if %key% geq %Space% (
rem Ascii character: insert it
Show %key%
for /F "delims=" %%a in ('Show %key%') do set "%1=!%1!%%a"
set /A len+=1
) else if %key% equ %BackSpace% (
rem Backspace: delete last character
if defined %1 (
Show %BackSpace% %Space% %BackSpace%
set "%1=!%1:~0,-1!"
set /A len-=1
) else (
rem Empty value
Show %Bell%
)
)
if %key% neq %Enter% goto nextKey
echo/
for /F "delims=" %%a in ("!%1!") do endlocal & set %1=%%a
exit /B
This way, you may use this line to solve your problem:
call :ReadInitVar color="For you the sky is " "Blue"
You may download Getkey.exe and Show.exe auxiliary programs, and review the original ReadLine.bat subroutine, from this site: Advanced Batch features via auxiliary .exe programs.
There is also another subroutine similar to ReadInitVar.bat above, but that display the user input in a different color field by using ColorShow.exe auxiliary program instead of Show.exe. You may review it here: http://www.dostips.com/forum/viewtopic.php?f=3&t=4198&p=23426#p23426