Almost there... Need to find and replace. Using for loop - batch-file

Question

I am trying to find and replace. I am using a for loop. I am learning but I am almost there. I have tried to find the answer but the sources have been a bit too confusing for me.
The delim is a blank space and as you can tell I am skipping 4 lines and doing the 2nd token.
I need what is found there at that spot to be replaced by var5a. I have it backwards, as I need %%F to equal var5a, not the other way around (as I have it written now). But don't know how to write it. Please explain how one can do this. I've tried using <<= but with no luck.
for /f "skip=4 tokens=2 delims= " %%F in (script.vbs) do (
set var5a=!var5a!%%F
)
I'm learning so please be kind.

Answer 1

#ECHO OFF
SETLOCAL
:: Replace token 2 (space-separated) in line 5 of a file with REPLACEMENT
:: Assumed the file exists, etc. and no line begins ":"
SET replacement=THIS IS THE REPLACEMENT TEXT
DEL newfile.txt 2>nul
FOR /f "tokens=1*delims=:" %%i IN ('findstr /n /r "$" ^<oldfile.txt') DO (
IF %%i==5 (
FOR /f "tokens=1,2* delims= " %%L IN ("%%j") DO >>newfile.txt ECHO %%L %replacement% %%N
) ELSE (>>newfile.txt ECHO.%%j)
)
TYPE oldfile.txt
ECHO ==== separator =======
FC oldfile.txt newfile.txt
Results:
Line one should not be changed
Line two should not be changed
Line three should not be changed
Line four should not be changed
changeme iwillbereplaced but only on this line
and notbereplaced on subsequent lines
including the previous line which was empty
==== separator =======
Comparing files oldfile.txt and NEWFILE.TXT
***** oldfile.txt
Line four should not be changed
changeme iwillbereplaced but only on this line
and notbereplaced on subsequent lines
***** NEWFILE.TXT
Line four should not be changed
changeme THIS IS THE REPLACEMENT TEXT but only on this line
and notbereplaced on subsequent lines
*****
There are difficulties - especially if the lines in your file start with a colon or contain quoted-strings or any of the usual batch gotchas like %
So - at long last I've worked out what you're doing. You omitted the critical information that the string in %%F is not only quoted, it also contains spaces.
Had you said that in the first place, you'd be hours further into your project, and I'd be richer by a handful of aspirin.
In order to load %%F with a quoted string, I've read the string from a file.
#ECHO OFF
SETLOCAL enabledelayedexpansion
:: Replace token 2 (space-separated) in line 5 of a file with REPLACEMENT
:: Assumed the file exists, etc. and no line begins ":"
SET replacement="THIS IS THE REPLACEMENT TEXT"
DEL newfile.txt 2>NUL
:: iwbr.txt just contains
:: "i will be replaced"
:: on a single line for loading into %%F as that is the target to be replaced
FOR /f "delims=" %%F IN (iwbr.txt) DO (
FOR /f "tokens=1*delims=:" %%i IN (
'findstr /n /r "$" ^<oldfile.txt'
) DO >>newfile.txt (
IF %%i==5 (
SET newline=%%j
CALL SET newline=%%newline:%%F=%replacement%%%
ECHO.!newline!
) ELSE (ECHO.%%j)
)
)
TYPE oldfile.txt
ECHO ==== separator =======
FC oldfile.txt newfile.txt
Results:
Line one should not be changed
Line two should not be changed
Line three "should" not be changed
Line four should not be changed
changeme "i will bereplaced" but only on this line
and notbereplaced on subsequent lines
including the "previous" line which was empty
including this "unbalanced-quote line...
==== separator =======
Comparing files oldfile.txt and NEWFILE.TXT
***** oldfile.txt
Line four should not be changed
changeme "i will bereplaced" but only on this line
and notbereplaced on subsequent lines
***** NEWFILE.TXT
Line four should not be changed
changeme "THIS IS THE REPLACEMENT TEXT" but only on this line
and notbereplaced on subsequent lines
*****

Answer 2

If you have Henri in %%F and you want to set the value of Henri to the current value of var5a then
set %%F=!var5a!
(!var5a! if you want the RUN-TIME value of var5a (provided you have ENABLEDELAYEDEXPANSION mode invoked) or %var5a% if you want the PARSE-TIME value)
Program to demonstrate that the answer does work:
#ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
::: WARNING! This will overwrite SCRIPT.VBS
DEL script.vbs 2>nul
FOR /l %%i IN (1,1,4) DO >>script.vbs ECHO ignore this line %%i
>>script.vbs ECHO Oh Henri - it does work
>>script.vbs ECHO Now try again
ECHO ===== here is script.vbs
TYPE script.vbs
ECHO ===== script.vbs ends
SET var5a=this is the value
SET henri
SET var5a
ECHO ===== now run the FOR loop...
for /f "skip=4 tokens=2 delims= " %%F in (script.vbs) do (
set %%F=!var5a!
)
SET henri
GOTO :eof
Results:
===== here is script.vbs
ignore this line 1
ignore this line 2
ignore this line 3
ignore this line 4
Oh Henri - it does work
Now try again
===== script.vbs ends
Environment variable henri not defined
var5a=this is the value
===== now run the FOR loop...
Henri=this is the value
Now - what do you mean by "it doesn't work"? It certainly does. If it's not doing what you want it to do, then demonstrate WHY you make the claim, otherwise we're left guessing.
For instance, the above will also set try to the value because Henri isn't the ONLY token that's number 2, space-delimited after 4 lines of the source file. That's easy to fix (but I'm not a mindreader - just a humble programmer)
(set notsetyet=Y)
for /f "skip=4 tokens=2 delims= " %%F in (script.vbs) do (
IF DEFINED NOTSETYET set %%F=!var5a!&(set notsetyet=)
)
But maybe "it didn't work" because it Henri was set to the wrong value. Or perhaps it crashed. We can't tell from your response.