Can I use or condition on When into a trigger? - database

Question

I'm trying to create a trigger on oracle database and i'm having troubles with when condition.
When i try to use it i get "invalid relational operator"
create or replace TRIGGER SQLTEST.TRIGGER_TESTE
AFTER INSERT OR UPDATE ON SQLDBA.VT_TABLE
FOR EACH ROW
WHEN (INSERTING OR NEW.FIELD_1 is null and OLD.FIELD_1 is not null or NEW.FIELD_1 <> OLD.FIELD_1)
DECLARE
VAR_FIELD_1 VT_LOG_TABLE.FIELD_1%TYPE;
BEGIN
SELECT SQLDBA.SEQ_LOG_TABLE.NEXtval into VAR_FIELD_1
FROM dual;
INSERT INTO VT_LOG_TABLE
(FIELD_0,VAR_FIELD_1,FIELD_2,FIELD_3,FIELD_1, FIELD_4 )
VALUES( :NEW.FIELD_0,VAR_FIELD_1, :NEW.FIELD_2, :NEW.FIELD_3, :NEW.FIELD_1,SYSDATE);
END TRIGGER_TESTE;
What's the right way to make that condition?

Answer 1

As graceemile says, the WHEN clause doesn't understand INSERTING. I'm not sure if you can rely on old.field_1 is null to indicate an insert since it looks like a nullable field (since new.field_1 can apparently be null). If you can't then you could just move the logic into the block:
create or replace trigger vt_trigger
after insert or update on vt_table
for each row
declare
do_logging boolean := false;
begin
if inserting then
do_logging := true;
elsif (:new.field_1 is null and :old.field_1 is not null)
or (:new.field_1 is not null and :old.field_1 is null)
or (:new.field_1 <> :old.field_1)
then
do_logging := true;
end if;
if do_logging then
insert into vt_log_table (field_0, var_field_1, field_2, field_3,
field_1, field_4)
values (:new.field_0, seq_log_table.nextval, :new.field_2, :new.field_3,
:new.field_1, sysdate);
end if;
end vt_trigger;
/
I've changed the check a bit to this:
elsif (:new.field_1 is null and :old.field_1 is not null)
or (:new.field_1 is not null and :old.field_1 is null)
or (:new.field_1 <> :old.field_1)
... to detect if field_1 has changed from null, to null, or from one non-null value to another; maybe you don't want that, the partial check just looked a bit odd to me. I'm assuming you only want to log if field_1 has changed in any way, or if you're inserting a new row of course.

Answer 2

I just tried something similar and Oracle doesn't like the INSERTING value in the WHEN condition. It appears to be OK with NEW and OLD, even if inserting.
From experimentation, it looks like your trigger will fire on INSERTS if you add this to your WHEN condition:
OR OLD.FIELD_1 IS NULL
So try something like this:
create or replace TRIGGER SQLTEST.TRIGGER_TESTE
AFTER INSERT OR UPDATE ON SQLDBA.VT_TABLE
FOR EACH ROW
WHEN (NEW.FIELD_1 is null and OLD.FIELD_1 is not null
or NEW.FIELD_1 <> OLD.FIELD_1
or OLD.FIELD_1 IS NULL)
DECLARE
... and so on
If that gets too complicated, you can create two triggers: one for UPDATE with the WHEN condition and one for INSERT, without conditions.
You could also try defining the trigger as AFTER INSERT OR UPDATE OF Field_1 ON VT_TABLE:
create or replace trigger vt_trigger
after insert or update of field_1 on vt_table
for each row
begin
insert into vt_log_table (field_0, var_field_1, field_2, field_3,
field_1, field_4)
values (:new.field_0, seq_log_table.nextval, :new.field_2, :new.field_3,
:new.field_1, sysdate);
end vt_trigger;
/