read from file via batch file - batch-file

Question

I have a file.txt that contains the paths of the oracles that installed on my machine.
from the registry
example this file contains:
ORACLE_HOME REG_SZ C:\oracle\product\11.2.0\dbhome_1
ORACLE_HOME REG_SZ C:\oracle\product\11.2.0\dbhome_2
I want via my batch file to insert all the paths of the oracles into a list or something like list.
How can I do it in batch file?
thanks!

Answer 1

Assuming you want a "list" of values in memory, not in a file:
I think most people prefer an "array" of values that can be accessed via an index value. (Note - batch does not have formal arrays, but they can be emulated).
The following simple code works great as long as none of the home paths contain !. Expansion of %%B will be corrupted if it contains ! and delayed expansion is enabled.
#echo off
setlocal enableDelayedExpansion
:: Read the file and create an "array" of home paths
:: This will fail if any of the paths contain !
set /a cnt=0
for /f "usebackq tokens=2*" %%A in ("file.txt") do (
set /a cnt+=1
set "home.!cnt!=%%B"
)
:: Access the "array" members
for /l %%N in (1 1 %cnt%) do echo !home.%%N!
You could probably run the above code for years in many environments and never run into a problem. But someone somewhere might include ! in the Oracle home path. There are a number of strategies to fix the above to deal with !. Below are three options:
Option 1 - The least amount of code, but the slowest due to CALL
#echo off
setlocal disableDelayedExpansion
:: Read the file and create an "array" of home paths
:: This will safely process all paths, regardless of value
set /a cnt=0
for /f "usebackq tokens=2*" %%A in ("file.txt") do (
set /a cnt+=1
call set "home.%%cnt%%=%%B"
)
:: Access the "array"
setlocal enableDelayedExpansion
for /l %%N in (1 1 %cnt%) do echo !home.%%N!
Option 2 - An interesting and efficient method using FINDSTR to count the rows.
#echo off
setlocal disableDelayedExpansion
:: Read the file and create an "array" of home paths
:: This will safely process all paths, regardless of value
set /a cnt=0
for /f "tokens=1,3* delims=: " %%A in ('findstr /n "^" "file.txt"') do (
set "home.%%A=%%C"
set "cnt=%%A"
)
:: Access the "array" members
setlocal enableDelayedExpansion
for /l %%N in (1 1 %cnt%) do echo !home.%%N!
Option 3 - An efficient method that uses delayed expansion toggling, but the most code
#echo off
setlocal disableDelayedExpansion
:: Read the file and create an "array" of home paths
:: This will safely process all paths, regardless of value
set /a cnt=0
for /f "usebackq tokens=2*" %%A in ("file.txt") do (
set /a cnt+=1
setlocal enableDelayedExpansion
for %%N in (!cnt!) do (
endlocal
set "home.%%N=%%B"
)
)
:: Access the "array"
setlocal enableDelayedExpansion
for /l %%N in (1 1 %cnt%) do echo !home.%%N!
It is also possible to have a list of home paths in a single variable. Each path should be enclosed by quotes. The paths could be delimited by space, comma, semicolon, equal, or tab. I chose space.
The size of the list is limited because the maximum size of a batch environment variable is ~8191 bytes. This solution is also relatively slow due to the CALL. Neither of these issues are likely to be a problem in the real world.
#echo off
setlocal disableDelayedExpansion
:: Read the file and create a space delimited list of quoted home paths
:: This will safely process all paths, regardless of value
for /f "usebackq tokens=2*" %%A in ("file.txt") do (call set list=%%list%% "%%~B")
:: optional - remove leading space
(set list=%list:~1%)
:: Display the list
echo list=%list%
:: Access the list members
for %%F in (%list%) do echo %%~F

Answer 2

for /f "tokens=3 delims= " %%a in (file.txt) do echo %%a >>paths.txt