Validation Rule Syntax - salesforce

Question

I have picklist with two values(A,B) and a custom field. If Values chosen other than B then the custom field should not be entered. If Value B is chosen then the custom field can be entered. What function to use. ? I m quite confused. Help Please

Answer 1

Something like this? I've used standard fields from Account, Rating is a picklist, ShippingCountry is text field.
Validation criteria:
ISPICKVAL(Rating, "Hot") && ISBLANK(ShippingCountry) ||
NOT(ISPICKVAL(Rating, "Hot")) && NOT(ISBLANK(ShippingCountry))
Error message:
Shipping Country is mandatory when Rating is "Hot". Please either
change the rating or clear the value in the Shipping Country field.
The condition is basically a XNOR if you're familiar with logic, simplification etc ;) But we don't have a XOR function in the functions reference.
You could also consider splitting it into 2 separate validation rules - this will let you write cleaner instructions what the user has to do "you've picked B -> fill this value!; you've picked A -> clear this value"

Answer 2

Using the example eyescream gave, you can further reduce the size of the condition like this:
ISPICKVAL( Rating, "Hot" ) = ISBLANK( ShippingCountry )
That is (spelled out):
if Rating is Hot and ShippingCountry is blank, then both conditions will be TRUE and equal with each other so the validation will activate and display the error
AND
if Rating is NOT Hot and Shippingcountry is NOT blank, then both conditions will be FALSE but equal with each other so the validation will activate and display the error
That type of shorter XOR expression might be handy when you have to specify a similar criteria for many fields, such as a validation that says "Shipping street, city, state and zip must be either all entered or all blank".
In such case you would enter:
ISBLANK( ShippingStreet ) != ISBLANK( ShippingCity )
|| ISBLANK( ShippingCity ) != ISBLANK( ShippingState )
|| ISBLANK( ShippingState ) != ISBLANK( ShippingPostalCode )
Notice the transitivity between each of the conditions linking the state of street to city all the way to postal code.
The expression basically means both conditions spelled out below:
if street is blank, then city should be blank and if city is blank, then state should be blank, and if state is blank, then postal code should be blank
AND
if street is NOT blank, then city should NOT be blank and if city is NOT blank, then state should NOT be blank, and if state is NOT blank, then postal code should NOT be blank