A12345678.textornumbers.textornumbers.txt to A12345678.txt - batch-file

Question

I try to create a batch file to automaticaly rename the files contained in a folder, from this structure: A12345678.textornumbers.textornumbers.txt to a more simple one: A12345678.txt
I tried something like this:
#echo off
ECHO Renaming files
Pause
:begin
ECHO Renaming txt files
for /r %%x in (A*.*.*.txt) do (REN "%%x" A*.txt)
ECHO Renaming finished
:end
pause
done
It does not return any error, but it does nothing...
EDITED:
Ok, the problem could be seen in other way: i want to rename the file remaining the first 9 characters and the extension.
I saw a similar question here:
Deleting characters from filename
I modified and adjusted to my case to have this:
#echo off
ECHO Renaming files
Pause
:begin
REM setlocal enabledelayedexpansion (the result is the same with and without this line)
set X=9
ECHO Renaming files
for /r %%f in (*.txt) do if %%f neq %~nx0 (
set "filename=%%~nf"
set "filename=!filename:~%X%,-%X%!"
ren "%%f" "!filename!%%~xf")
ECHO Done
ECHO Processing finished
:end
pause
done
But the result is this:
Blockquote
!filename!.txt
This is for the first image in the directoy, and errors (Such file already exist) for the others.
EDITED 2:
Thanks to the replies and other information i found on internet, here is the solution i had: to remove the last characters of the filename, because i want to remain ever the first 9 characters:
#echo off
ECHO renaming files
ECHO.
Pause
:begin
set ext=QUB
set num=17
FOR /f "tokens=*" %%f in ('dir /b /a *.%ext%') do call :lab %%f
ECHO Done
pause
Exit
:lab
set original=
set original=%*
set newname=
call set newname=%%original:.%ext%=%%
call set newname=%%newname:~0,-%num%%%.%ext%
if "%newname%"==".%ext%" (goto :eof)
ren "%original%" "%newname%"
ECHO %newname%
goto :eof
This is not my code, but the solution i used from others (by Carlitos.dll). I hope it could help to others with similar problems. Thanks for your ideas and help!

Answer 1

The script does do something, but nothing useful - It renames each file to it's original name :-(
It all has to do with the rules for how REN works with wildcards. I had never seen any proper explanation of how REN works posted anywhere. So a few weeks ago I did extensive experiments and developed a set of rules that explain all the behavior I observed.
You can find my results at How does the Windows RENAME command interpret wildcards? on the StackExchange SuperUser site.
Your problem is easily solved by replacing * with many ? in your target name. Just make sure the number of ? is greater than or equal to the max leading name length that you will process. You also don't need to specify the leading A if you are not changing the value.
for /r %%x in (A*.*.*.txt) do ren "%%x" ?????????????????????.txt
The above must iterate each file. It may be a bit faster to iterate the folders only, though I haven't tested
for /r /d %%x in (.) do ren "%%x\A*.*.*.txt" ?????????????????????.txt
It is also possible to parse the name with FOR /F so that you don't have to worry about the number of ?.
for /r %%x in (a*.*.*.txt) do (
for /f "delims=." %%n in ("%%~nx") do ren "%%x" "%%n.txt"
)
EDIT based on revised question
To simply preserve up to the 1st 9 characters and the .txt extension, the solution is even easier, just use 9 ?:
for /r /d %%x in (.) do ren "%%x\*.txt" ?????????.txt
If you want to rename all files, not just .txt files, then
for /r %%F in (*) do ren "%%F" "?????????%%~xF"

Answer 2

You could also do something like this:
for %%x in (*.textornumbers.txt) do (
set nam=%%x
if "!nam!" neq "!nam:.textornumbers=!" ren %%x !nam:.textornumbers=!
)

Answer 3

Using ~-modifiers, you could do the following:
Take just the name from the original full path and name (& extension):
FOR /R %%A IN (A*.*.*.txt) DO (
... %%~nA ...
)
That will turn a D:\path\A*.*.*.txt to just an A*.*.*.
Take just the name from the result of #1:
FOR /R %%A IN (A*.*.*.txt) DO (
FOR %%B IN ("%%~nA") DO (
... %%~nB ...
)
)
That will leave you with A*.*.
Take just the name from #2:
FOR /R %%A IN (A*.*.*.txt) DO (
FOR %%B IN ("%%~nA") DO (
FOR %%C IN ("%%~nB") DO (
... %%~nC ...
)
)
)
which will give you A*.
Extract the extension from the original name and concatenate it with #3. That will be the final name, A*.txt, which you can now supply to the RENAME command:
FOR /R %%A IN (A*.*.*.txt) DO (
FOR %%B IN ("%%~nA") DO (
FOR %%C IN ("%%~nB") DO (
RENAME "%%A" "%%~nC%%~xA"
)
)
)