Batch file to rename files in a folder and back again - batch-file

Question

A slightly archaic question I'm afraid but here goes:
I have a program which produces some .RAW files in a sequence eg.
Example_1.RAW
Example_2.RAW
This then adds extra significant figures to the number as necessary, eg.
Example_10.RAW
Example_200.RAW
I have a need to convert these file names into numbers for running through a batch processor that then produces more files as outputs. I've written a batch file that does the renaming and stores the old and new filenames in a text file, my code is:
#echo off
set i=1
echo Running Batch Rename
for %%f in (*.RAW) do (set file=%%f) & CALL :rename
:rename
echo %i% >>Names.txt
echo %file% >>Names.txt
echo. >>Names.txt
ren %file% %i%.RAW
set /A i+=1
This then renames all my .RAWs as 1.RAW, 2.RAW etc and creates Names.txt with the old and new filenames. Thanks to the way in which DOS processes numbers this does mean that I get a slightly wonky numbering process, ie it will process Ex_1, Ex_10, Ex_100, Ex_101 as 1, 2, 3, 4 which would lead to more work in the post processing of these results in order to get the right results in the right places.
Would it be possible to write another batch file that takes the Names.txt and reverses the process for the output files? So it will take a folder with 1.raw, 1.something, 1.something else, refer to the Names.txt and rename them to Example_1.raw etc?

Answer 1

This should do the job
#echo off
set cnt=0
del Names.txt > nul 2>&1
echo Running Batch Rename
for %%f in (*.RAW) do (
set "file=%%f"
CALL :renameToNumber
)
echo .. Do the jobs ...
rem ** As sample: copy the file
copy *.raw *.some
call :renameBack
exit /b
:renameToNumber
set /A cnt+=1
set "number=00000%cnt%"
set "number=%number:~-4%"
(echo %number% %file%) >> Names.txt
ren "%file%" %number%.RAW
exit /b
:renameBack
for /F "tokens=1,*" %%A in (names.txt) DO (
set "number=%%A"
set "filename=%%~nB"
call ren %%number%%.* "%%filename%%_%%number%%.*"
call echo ren %%number%%.* "%%filename%%_%%number%%.*"
)
exit /b

Answer 2

I was able to adapt the above code, to function within an existing batch routine, by testing for the last file in the directory - using 'if errorlevel' - so that the routine did not exit after the last file was reached but instead returned to my routine.
:: *** Renumber .JPG files ***
setlocal EnableDelayedExpansion
set dir=C:%homepath%\Desktop\Temp
:: Create variable and set to zero
set cnt=0
:: For each file in specified class
for %%f in (%dir%\*.jpg) do (
:: Get name of file
set "file=%%f"
:: Run specified Subroutine
CALL :renameToNumber
)
:renameToNumber
:: Increment variable by 1
set /A cnt+=1
:: Preceed value of variable with 00000
set "number=00000%cnt%"
:: Delete all but final 2 digits
set "number=%number:~-2%"
:: Store new and original name of file
(echo %number% %file%) >> Names.txt
:: Rename file
ren "%file%" %number%.jpg
:: Quit Subroutine if no further files
if errorlevel==1 goto :Continue
:: Loop back to start of Subroutine
exit /b
:Continue
:: *** Zip the image files into an RAR file ***
SET rar=C:\Program Files (x86)\WinRAR\RAR.exe
"%rar%" a -ep -m0 temp.rar "%dir%\*.*"

Answer 3

You can prepare two batch files, one to rename RAW files to 1.RAW, 2.RAW, etc, and a second one to reverse this process back.
Rename script stores original names of RAW files in corresponding txt files:
#echo OFF
#setlocal ENABLEDELAYEDEXPANSION
set I=1
for %%G in (*.RAW) do (
set ORIGINAL_NAME=%%~nG
(
REM Try to rename file
ren "%%G" "!I!.RAW"
) && (
REM Renaming was successful
> "!I!.txt" echo !ORIGINAL_NAME!
set /A I+=1
) || (
REM Renaming was a failure
echo Cannot rename [!ORIGINAL_NAME!.RAW] file.
)
)
#endlocal
And the RenameBack script uses that information to restore names of all corresponding files:
#echo OFF
#setlocal ENABLEDELAYEDEXPANSION
for %%F in (*.txt) do (
set BASENAME=%%~nF
REM Read original name from txt file
for /F %%G in (%%F) do (
REM iterate over all corresponding files
for %%H in (!BASENAME!.*) do (
set EXTENSION=%%~xH
REM Remove dot from extension string
set EXTENSION=!EXTENSION:~1!
if not "!EXTENSION!" == "txt" (
REM Process files
(
REM try to rename corresponding file to old name
ren "!BASENAME!.!EXTENSION!" "%%G.!EXTENSION!"
) && (
REM Operation was successful - remove TXT file
del /F /Q "%%F"
) || (
REM Something went wrong
echo Cannot restore old name for file [!BASENAME!.!EXTENSION!].
)
)
)
)
)
#endlocal