i want a menu where you can change background color and foreground color - batch-file

Question

How do I get the code below to work, or something that will do the same.
#echo off
:menu
cls
echo 1. Settings
echo.
set /p variable= Type the number of your choosing:
if %variable% equ 1 goto settings
if %variable% neq 1 goto menu
:settings
cls
echo 1. Text color
echo.
echo 2. Back
echo.
set /p variable= Type the number of your choosing:
if %variable% equ 1 goto textcolor
if %variable% neq 1 goto settings
:textcolor
cls
echo Text color
echo.
echo 1. Blue
echo.
echo 2. Gray
echo.
set /p variable= Type the number of your choosing:
if %variable% equ 1 goto backgroundcolor
if %variable% equ 2 goto backgroundcolor
if %variable% neq 1 goto textcolor
:backgroundcolor
::code to make the text the color I chose
cls
echo Background color
echo.
echo 1. Green
echo.
echo 2. Purple
echo.
echo 3. Menu
echo.
set /p variable= Type the number of your choosing:
if %variable% equ 1 goto done
if %variable% equ 2 goto done
if %variable% equ 3 goto menu
if %variable% neq 1 goto backgroundcolor
:done
::code to make the background the color I chose
goto start
:start
cls
echo Now the text is the color I chose and the background is the color I chose
pause
If you picked the wrong color and chose to go back then I dont want it to reset the background color when you chose the text color
I can get it to work but I need to do every color for each color and that is so much text and it resets.

Answer 1

First you could use the choice command instead of set /p for user input. You can learn more about it by using the choice /? command.
Second you should create variables to not loose the changes made. for example:
set textColor=f
set backgroundColor=0
At no point in your code did you set a color value to anything nor did you use the color command.
This should be what you wanted to do:
#echo off
set textColor=f
set backgroundColor=0
:menu
color %backgroundColor%%textColor%
cls
echo 1. Settings
echo.
choice /n /c:1
if %errorlevel% == 1 goto :settings
goto :menu
:settings
cls
echo 1. Text color
echo.
echo 2. Back
echo.
choice /n /c:12
if %errorlevel% == 2 goto :menu
if %errorlevel% == 1 goto :textcolor
goto :settings
:textcolor
cls
echo Text color
echo.
echo 1. Blue
echo.
echo 2. Gray
echo.
choice /n /c:12
if %errorlevel% == 2 set textColor=8&&goto :backroundcolor
if %errorlevel% == 1 set textColor=1&&goto :backroundcolor
goto :textcolor
:backroundcolor
cls
echo Backroundcolor
echo.
echo 1. Green
echo.
echo 2. Purple
echo.
echo 3. Menu
echo.
choice /n /c:123
if %errorlevel% == 3 goto :menu
if %errorlevel% == 2 set backgroundColor=5&&goto :start
if %errorlevel% == 1 set backgroundColor=2&&goto :start
goto :backroundcolor
:start
cls
color %backgroundColor%%textColor%
echo Now the text is the color is "%textColor%" and the backround is "%backgroundColor%"
pause
If you want to keep the text input you can use following:
#echo off
set textColor=f
set backgroundColor=0
:menu
color %backgroundColor%%textColor%
cls
echo 1. Settings
echo.
set /p variable= Type the number of your choosing:
if %variable% == 1 goto :settings
goto :menu
:settings
cls
echo 1. Text color
echo.
echo 2. Back
echo.
set /p variable= Type the number of your choosing:
if %variable% == 2 goto :menu
if %variable% == 1 goto :textcolor
goto :settings
:textcolor
cls
echo Text color
echo.
echo 1. Blue
echo.
echo 2. Gray
echo.
set /p variable= Type the number of your choosing:
if %variable% == 2 set textColor=8&&goto :backroundcolor
if %variable% == 1 set textColor=1&&goto :backroundcolor
goto :textcolor
:backroundcolor
cls
echo Backroundcolor
echo.
echo 1. Green
echo.
echo 2. Purple
echo.
echo 3. Menu
echo.
set /p variable= Type the number of your choosing:
if %variable% == 3 goto :menu
if %variable% == 2 set backgroundColor=5&&goto :start
if %variable% == 1 set backgroundColor=2&&goto :start
goto :backroundcolor
:start
cls
color %backgroundColor%%textColor%
echo Now the text is the color is "%textColor%" and the backround is "%backgroundColor%"
pause

Answer 2

Mmmm... This is "something that will do the same"...
#echo off
setlocal EnableDelayedExpansion
set /A textColor=15, backColor=0
set "color=0123456789ABCDEF"
:option2-3
:menu
cls
echo 1. Settings
echo X. eXit
echo/
choice /C 1X /N /M "Select an option: "
goto option1-%errorlevel%
:option1-1 Settings
echo/
echo 1. Text color
echo 2. Background color
echo 3. Reset color
echo X. eXit
echo/
choice /C 123X /N /M "Select an option: "
goto option2-%errorlevel%
:option2-1 Text color
echo/
echo/
echo Text color
echo/
for /F "delims=" %%a in ('color /? ^| findstr /B /C:" "') do echo %%a
echo/
choice /C %color% /N /M "Select text color: "
set /A "textColor=%errorlevel%-1"
goto setColor
:option2-2 Background color
echo/
echo/
echo Background color
echo/
for /F "delims=" %%a in ('color /? ^| findstr /B /C:" "') do echo %%a
echo/
choice /C %color% /N /M "Select background color: "
set /A "backColor=%errorlevel%-1"
::goto setColor
:setColor
color !color:~%backColor%,1!!color:~%textColor%,1!
goto menu
:option2-3 Reset color
color
goto menu
:option1-2 Exit
echo Exit