Compare two files with awk and map congregated multiple values - loops

Question

I have two files I need to compare and map a value to which multiple rows match.
My mapping file (map.csv) looks like:
id,name
123,Hans
123,Britta
232,Peter
343,Siggi
343,Horst
The data file (data.csv) is
contact,id,names
m#a.de,123,
ad#23.com,343,
adf#er.org,123,
af#go.er,232,
llk#fh.com,343,
ad#wer.org,789,
The disired output should look like this
contact,id,names
m#a.de,123,Hans Britta
ad#23.com,343,Siggi Horst
adf#er.org,123,Hans Britta
af#go.er,232,Peter
llk#fh.com,343,Siggi Horst
ad#wer.org,789,NO ENTRY
There are multiple values for one ID in the mapping-file and they should be printed space-separated into the column names of the data-file. If there is no ID in the mapping file "NO ENTRY" should be printed instead.
This is the awk-command
awk 'NR==FNR{a[$1];next}{print $0,($2 in a)? a[$2]:"NO ENTRY"}' map.csv data.csv
I clearly fail because I do not know how to loop through the mapping file for getting multiple values to one id (or currently any value at all).

Answer 1

With your shown samples please try following.
awk '
BEGIN{
FS=OFS=","
}
FNR==NR{
arr[$1]=(arr[$1]?arr[$1] " ":"")$2
next
}
FNR==1{
print
next
}
{
sub(/,$/,"")
print $0,($2 in arr)?arr[$2]:"NO ENTRY"
}
' map.csv data.csv
Explanation: Adding detailed explanation for above.
awk ' ##Starting awk program from here.
BEGIN{ ##Starting BEGIN section of this program from here.
FS=OFS="," ##Setting FS and OFS as comma here.
}
FNR==NR{ ##Checking condition which will be TRUE when map.csv is being read.
arr[$1]=(arr[$1]?arr[$1] " ":"")$2 ##Creating arr with index of $1 and which has value of $2 and keep concatenating its value with same index.
next ##next will skip all further statements from here.
}
FNR==1{ ##Checking condition if this is first line of data.csv then do following.
print ##Printing current line here.
next ##next will skip all further statements from here.
}
{
sub(/,$/,"") ##Substituting last comma with NULL here.
print $0,($2 in arr)?arr[$2]:"NO ENTRY" ##Printing current line and printing either value of arr with index of $2 OR printing NO ENTRY as per requirement.
}
' map.csv data.csv ##Mentioning Input_file names here.

Answer 2

You can use two rules in your case. One to capture the data from map.csv and then a second rule to output the results, e.g.
(edit -- updated to match 1st row of output exactly)
awk -F, '
NR==FNR { if (FNR > 1) a[$1]=a[$1]" "$2; next }
FNR==1 { print; next }
{ printf "%s,%s,%s\n", $1, $2, a[$2]?a[$2]:"NO ENTRY" }
' map.csv data.csv
The first rule is qualified by NR=FNR (current record number equal to the file record number -- e.g. the first file). The second rule is only run on the second file and outputs the heading row unchanged before outputting the aggregated data.
Example Use/Output
You can simply select-copy and middle-mouse-paste the command above into an xterm with the current directory holding map.csv and data.csv which results in the following:
$ awk -F, '
> NR==FNR { if (FNR > 1) a[$1]=a[$1]" "$2; next }
> FNR==1 { print; next }
> { printf "%s,%s,%s\n", $1, $2, a[$2]?a[$2]:"NO ENTRY" }
> ' map.csv data.csv
contact,id,names
m#a.de,123, Hans Britta
ad#23.com,343, Siggi Horst
adf#er.org,123, Hans Britta
af#go.er,232, Peter
llk#fh.com,343, Siggi Horst
ad#wer.org,789,NO ENTRY
Alternative
An alternative that does the exact same thing, but simplifies (slightly) by explicitly setting OFS="," before output begins allowing the use of print instead of printf would be:
awk -F, '
NR==FNR { if (FNR > 1) a[$1]=a[$1]" "$2; next }
FNR==1 { OFS=","; print; next }
{ print $1, $2, a[$2]?a[$2]:"NO ENTRY" }
' map.csv data.csv
(same output)