How to convert heading of file content into column using awk? - arrays

Question

I am trying to convert heading of file content into column using awk, below is my input file -
abc.txt
1234|43245
4325|65123
5432|12342
bcd.txt
865|432
324|543
123|654
cde.txt
12|321
21|123
32|123
output :
abc.txt|1234|43245
abc.txt|4325|65123
abc.txt|5432|12342
bcd.txt|865|432
bcd.txt|324|543
bcd.txt|123|654
cde.txt|12|321
cde.txt|21|123
cde.txt|32|123
Explanation :
Fetch the filename(abc.txt) where NR==1 and put it into an array a or variable and print it will the file contents and when the file contents are completed create a blank line.
I was trying to create two array a one for NF=1 and another array b for NF>1 and loop on array b to merge file content with array a but still trying to figure out a solution.

Answer 1

In awk:
$ awk 'BEGIN{FS=OFS="|"} NF==1{h=$0} {print (NF==1?"": h OFS $0)}' file
abc.txt|1234|43245
abc.txt|4325|65123
abc.txt|5432|12342
bcd.txt|865|432
bcd.txt|324|543
bcd.txt|123|654
cde.txt|12|321
cde.txt|21|123
cde.txt|32|123
Downside is, that it prints an empty line in the beginning. If you can't live with that, add NR==1{next} before the printing block - or better yet: see #EdMorton's comment below.
Explained:
BEGIN{ FS=OFS="|" } # set delimiters
NF==1{ h=$0 } # if NF==1 it's header time, store it to h
# NR==1{ next } # to remove the leading enter, apply this
{ print (NF==1 ? "" : h OFS $0) } # print an empty record or the record with header

Answer 2

So here is my solution:
awk 'BEGIN{ OFS = "|"} /[a-z].[a-z]/{ if ($0 != header && NR > 1){print ""}; header = $0 }/[0-9]\|[0-9]/{ numbers = $0; print header, numbers }' yourfile
Output:
abc.txt|1234|43245
abc.txt|4325|65123
abc.txt|5432|12342
bcd.txt|865|432
bcd.txt|324|543
bcd.txt|123|654
cde.txt|12|321
cde.txt|21|123
cde.txt|32|123
It is without any arrays but it seems to work.

Answer 3

Use the following awk approach:
awk '{ if($1~/[a-z]+.txt/) { if(NR != 1) {print ""} h=$1;next } print h"|"$1;}' testfile
The output:
abc.txt|1234|43245
abc.txt|4325|65123
abc.txt|5432|12342
bcd.txt|865|432
bcd.txt|324|543
bcd.txt|123|654
cde.txt|12|321
cde.txt|21|123
cde.txt|32|123
Explanation:
if($1~/[a-z]+.txt/) - the condition checks if current column $1 matches the pattern /[a-z]+.txt/(header column)
h=$1;next - if a column matching the pattern is found, saves header value e.g. abc.txt into variable h and skips a header line via next
if(NR != 1) {print ""} - prints a linebreak if it's not the first occurance of a header line
print h"|"$1; - prints a header value with a separator and each next subsequent line

Answer 4

awk -F '|' '{if(NF==2)$0=F"|"$0;else{F=$1;$0=""}}NR>1' YourFile
self commented:
# use | as separator
awk -F '|' '
# for every lines
{
# line with "data" have 2 field
if(NF==2) {
# add File nameand "|" in front of current line
$0 = F"|"$0
}
else {
# File name is field 1
F=$1
# change line to empty line
$0=""
}
}
#print line (in new state, ater 1st line), default action of a trigger
NR>1
' YourFile