Bat file to remove data from text file - batch-file

Question

I have bat file which split my data from one row into multiple rows as expected but it is taking unnecessary data as well.
Data in txt file-
Data will be in same format as below
85:85123, ,Smith,181215:image.tif,image2.tif,image3.tif
85:85456, ,Richard,184985:image4.tif,image5.tif
85:85789, ,Aly,589456:image.tif
Output I am getting is:
123,
123,smith
123,image.tif
123,image2.tif
123,image3.tif
456,
456,Richard
456,image4.tif
456,image5.tif
789,
789,Aly
789,image.tif
Output which i want:
123,image.tif
123,image2.tif
123,image3.tif
456,image4.tif
456,image5.tif
789,image.tif
I only want unique number with image name on every row but I am getting unique number with one blank value and first name as well.
#echo off
> "Output.csv" (
for /F "usebackq tokens=1-2* delims=: " %%A in ("transact.txt") do (
set "NUM=%%B" & set "LIST=%%C"
setlocal EnableDelayedExpansion
for %%D in ("!NUM:*%%A=!") do (
for %%E in ("!LIST:,=" "!") do (
endlocal
echo(%%~D %%~E
setlocal EnableDelayedExpansion
)
)
endlocal
)
)

Answer 1

Well, you seem to want to filter out all files whose names are not image followed by an optional number and followed by .tif, which could be done by inserting a bit of code (see rem remarks):
#echo off
> "Output.csv" (
for /F "usebackq tokens=1-2* delims=:, " %%A in ("transact.txt") do (
set "NUM=%%B" & set "LIST=%%C"
setlocal EnableDelayedExpansion
for %%D in ("!NUM:*%%A=!") do (
for %%E in ("!LIST:,=" "!") do (
endlocal
rem // Store several interim values into variables:
set "ITEM=%%~nE" & set "EXT=%%~xE" & set "NUM=%%~D"
setlocal EnableDelayedExpansion
rem /* Split file name at first numeric part; the preceding `_` just
rem ensures that the part before the first number is not empty,
rem because then files like `012image3.tif` became handled wrongly;
rem everything up to the first colon `:` becomes removed: */
for /F "tokens=1* delims=0123456789" %%I in ("_!ITEM:*:=!") do (
endlocal
rem /* Ensure that the part behind the first numeric part (`%%J`) is
rem empty, that the name part in front of the number is `image`,
rem and that the file extension is `.tif`: */
if "%%J" == "" if /I "%%I" == "_image" if /I "%%~xE" == ".tif" (
setlocal EnableDelayedExpansion
echo(!NUM!,!ITEM:*:=!!EXT!
endlocal
)
setlocal EnableDelayedExpansion
)
)
)
endlocal
)
)

Answer 2

Just 3 minimal changes are necessary, to get your desired output.
:: Q:\Test\2019\09\09\SO_57856028.cmd
#echo off
> "Output.csv" (
for /F "usebackq tokens=1-4* delims=:, " %%A in ("transact.txt") do (
set "NUM=%%B" & set "LIST=%%E"
setlocal EnableDelayedExpansion
for %%D in ("!NUM:*%%A=!") do (
for %%E in ("!LIST:,=" "!") do (
endlocal
echo(%%~D,%%~E
setlocal EnableDelayedExpansion
)
)
endlocal
)
)