How to ask a question but only able to write numbers? - batch-file

Question

set PenaltyLimit = 0
:NewPass
echo Create a penalty limit
set/p "NewPenaltyLimit=>"
--> if %NewPenaltyLimit%==Numbers?? do (
#echo %NewPenaltyLimit% >> File/PenaltyLimit.txt)
FOR /F "usebackq tokens=* delims=" %%W in ("File/PenaltyLimit.txt") do SET PenaltyLimit=%%W
goto lock
:Fail2
#set /a penalty = %penalty% + 1
if %penalty%==%penaltylimit% goto DELETE
goto FAIL
What would you put in exchange for the line with the "-->"
Instead of breaking the batch file, writing something random, is it possible that you could somehow either stop someone entirely from writing anything but numbers or make it so the batch file will only read numbers? (Someone what example above this text)

Answer 1

#echo off
setlocal
:NewPass
echo Create a password
set/p "newpass=>" || goto :NewPass
:NewPenaltyLimit
cls
echo Create a penalty limit, Numbers only
set /p "NewPenaltyLimit=>" || goto :NewPenaltyLimit
set "NewPenaltyLimit=%NewPenaltyLimit:"=%"
if not defined NewPenaltyLimit goto NewPenaltyLimit
for /f "delims=1234567890" %%A in ("%NewPenaltyLimit%") do goto NewPenaltyLimit
cls
ping localhost -n 2 > nul
echo You chose %NewPenaltyLimit% goto lock
If you delimit the value of %NewPenaltyLimit% by integers
of 1234567890, the do goto :newPass should only happen
if characters other than integers exist.
Due to possibility of double quotes being input to the set /p prompt
which could cause a syntax error when expanded as text when the code
is parsed.
The double quotes will be substituted (removed) from the input value
immediately after input. This means that "86" will become 86 and
will be accepted as a valid number.
Example values:
a1 delimited creates a token with value of a which causes
the goto :NewPenaltyLimit to happen.
12 delimited creates no token as 1 and 2 are both delimiters.
If Delayed Expansion is allowed to be enabled.
This version can handle the input without removing double quotes:
#echo off
setlocal
:NewPass
echo Create a password
set/p "newpass=>" || goto :NewPass
:NewPenaltyLimit
cls
echo Create a penalty limit, Numbers only
set /p "NewPenaltyLimit=>" || goto :NewPenaltyLimit
setlocal enabledelayedexpansion
for /f "delims=1234567890" %%A in ("!NewPenaltyLimit!") do (
endlocal
goto NewPenaltyLimit
)
endlocal
cls
ping localhost -n 2 > nul
echo You chose %NewPenaltyLimit% goto lock
Delayed Expansion is only needed for only the for loop,
so this may be a better version.
!NewPenaltyLimit! is not expanded in the code when the code is parsed,
which means an input such as "86" will not cause error and will not be
accepted as a vaild number, as it has double quotes.
References:
View for /? for more helpful information.
View set /? for the information about substitution used in this answer.
View setlocal /? and if /? about Delayed Expansion.

Answer 2

You can try with embedding a powershell code:
<# : batch portion
#echo off & setlocal
for /f "tokens=*" %%a in ('powershell -noprofile "iex (${%~f0} | out-string)"') do set "number=%%a"
echo you've entered %number%
endlocal
goto :EOF
: end batch / begin powershell #>
do {
[Console]::Error.Write("Enter a number:")
$inputString = read-host
$value = $inputString -as [Double]
$ok = $value -ne $NULL
if ( -not $ok ) {[Console]::Error.WriteLine("You must enter a numeric value") }
}
until ( $ok )
write-host "$value"
One advantage is that this can support few types as Integer,Double,Unsigned integer and so on (in this case it is Double.)
You can try also with embedded jscript code (can be used on old XP machines):
#if (#X) == (#Y) #end /* JScript comment
#echo off
for /f "tokens=*" %%a in ('cscript //E:JScript //nologo "%~f0" "%~nx0" %* ') do set "number=%%a"
echo you've entered %number%
exit /b %errorlevel%
#if (#X)==(#Y) #end JScript comment */
WScript.StdErr.Write("Enter a number:");
WScript.StdIn.Read(0);
var strMyName = WScript.StdIn.ReadLine();
var num=parseInt(strMyName);
while(isNaN(num)){
WScript.StdErr.Write("Enter a number:");
WScript.StdIn.Read(0);
var strMyName = WScript.StdIn.ReadLine();
var num=parseInt(strMyName);
}
WScript.StdOut.WriteLine(num);

Answer 3

You can't use spaces around == comparisions. Your code says if %NewPenaltyLimit%<space>==<space>Numbers?? which will never match.