How to correctly delete and update array elements? - arrays

Question

I'm trying to send mass email based on certain condition.
I created a dynamic array that stores all the mail addresses. Idealy, if the checkInbox = true,
it will remove the email from the array, so that it wont be send to the user.
Now, It is sending to all the user. I try to debug my checkInbox, but it is returning the correct
sender-email address(which is me) within the condition.
Example output of the array with A = true
I can't seem to find my mistake. Any help is appreciated.
Thanks to #YowE3K for providing the MCVE example
Sub test()
Dim fpemail
Dim cnt As Long
cnt = 4
ReDim fpemail(cnt)
fpemail(1) = "A"
fpemail(2) = "B"
fpemail(3) = "A"
fpemail(4) = "D"
For i = 1 To cnt
If fpemail(i) = "A" Then
Call DeleteElementAt(i, fpemail)
End If
Next
Debug.Print fpemail(1) ' displays "A"
Debug.Print fpemail(2) ' displays "B"
End Sub
Public Sub DeleteElementAt(ByVal index As Integer, ByVal arr As Variant)
Dim i As Integer
For i = index + 1 To UBound(arr)
arr(i - 1) = arr(i)
Next
' Shrink the array by one, removing the last one
ReDim Preserve arr(UBound(arr) - 1)
End Sub

Answer 1

An MCVE of your problem would look like this:
Sub test()
Dim fpemail
Dim cnt As Long
cnt = 4
ReDim fpemail(cnt)
fpemail(1) = "A"
fpemail(2) = "B"
fpemail(3) = "A"
fpemail(4) = "D"
For i = 1 To cnt
If fpemail(i) = "A" Then
Call DeleteElementAt(i, fpemail)
End If
Next
Debug.Print fpemail(1) ' displays "A"
Debug.Print fpemail(2) ' displays "B"
End Sub
Public Sub DeleteElementAt(ByVal index As Integer, ByVal arr As Variant)
Dim i As Integer
For i = index + 1 To UBound(arr)
arr(i - 1) = arr(i)
Next
' Shrink the array by one, removing the last one
ReDim Preserve arr(UBound(arr) - 1)
End Sub
There are several issues with that code:
The procedure declaration for DeleteElementAt says that arr is passed ByVal. Therefore only a copy of the array is passed to the function, avoiding any possibility of changes affecting the calling routine. You need to pass it ByRef.
Once you delete an element from the array (e.g. the first element) what used to be the second element has become the new first element, and what used to be the third element is the new second element, etc. Thus your For i = 1 to cnt loop would be skipping over positions that had been moved to earlier positions. (Of course, this wouldn't be an issue until after the first problem was resolved.)
A refactored version of the code might look like:
Sub test()
Dim fpemail
Dim cnt As Long
Dim i As Long
cnt = 4
ReDim fpemail(cnt)
fpemail(1) = "A"
fpemail(2) = "B"
fpemail(3) = "A"
fpemail(4) = "D"
i = 1
Do While i <= cnt
If fpemail(i) = "A" Then
Call DeleteElementAt(i, fpemail)
cnt = cnt - 1 ' Reflects the fact that we now have one less position
' Don't change i, because we still need to process
' what has now been moved into that position of
' the array
Else
i = i + 1 ' Increment i so that we look at the next position
' of the array
End If
Loop
Debug.Print fpemail(1) ' displays "B"
Debug.Print fpemail(2) ' displays "D"
End Sub
Public Sub DeleteElementAt(ByVal index As Integer, ByRef arr As Variant)
Dim i As Long
For i = index + 1 To UBound(arr)
arr(i - 1) = arr(i)
Next
' Shrink the array by one, removing the last one
ReDim Preserve arr(UBound(arr) - 1)
End Sub

Answer 2

Or you can use a Collection in place of your array.
As easy to populate and as easy to read and update.
Dim fpemail As Collection, i As Long
Set fpemail = New Collection
With fpemail
.Add "A"
.Add "B"
.Add "A"
.Add "D"
For i = .Count To 1 Step -1
If .Item(i) = "A" Then
.Remove (i)
End If
Next
Debug.Print fpemail(1)
Debug.Print fpemail(2)
End With