How do I sort a Tcl array by values? - arrays

Question

how to sort an Array output for example
Sample input coming from
puts "$word $count($word)"}
Sample Input
Roger 15
Martin 18
Jemmy 16
Jon 12
Sara 12
Expected Output
Martin 18
Jemmy 16
Roger 15
Jon 12
Sara 12

Answer 1

Tcl's arrays are unsorted, always, and indeed the order of the elements changes from time to time as you add elements in (when the underlying hash table is rebuilt). To get the output you want, you're best off getting the contents of the array and using lsort with the -stride 2 option:
# Convert the array to a Tcl list
set contents [array get count]
# First sort by name, as a secondary key
set contents [lsort -stride 2 -index 0 $contents]
# Then sort by count, descending, as a primary key
set contents [lsort -stride 2 -index 1 -integer -decreasing $contents]
# Print the values
foreach {name score} $contents {
puts "$name $score"
}
The -stride option requires Tcl 8.6.
In older versions of Tcl, you have to pack things up into a list of tuples:
# Convert the array to a list of pairs
set contents {}
foreach {name score} [array get count] {
lappend contents [list $name $score]
}
# Do the sorting
set contents [lsort -index 0 $contents]
set contents [lsort -index 1 -integer -decreasing $contents]
# Print the values
foreach pair $contents {
# Unpack; *not* needed here, but useful for anything more complicated
foreach {name score} $pair break
# You could use “lassign $pair name score” but you're on 8.4
puts "$name $score"
}
Note that Tcl 8.4 is unsupported software, not even for security issues, and that 8.5 has only got a year or two more extended support lifetime left. There's a limit to how long we'll hold people's hands…

Answer 2

You probably have something like this
array set count { Roger 15 Martin 18 Jemmy 16 Jon 12 Sara 12 }
foreach word [array names count] {puts "$word $count($word)"}
Jemmy 16
Sara 12
Jon 12
Martin 18
Roger 15
what you want to do is to transform the array into a list, step over it in pairs and sort the pairs based on the number:
foreach {name num} \
[lsort -integer -decreasing -stride 2 -index 1 [array get count]] \
{puts "$name $num"}
Martin 18
Jemmy 16
Roger 15
Sara 12
Jon 12
refs:
http://www.tcl.tk/man/tcl8.6/TclCmd/lsort.htm
http://www.tcl.tk/man/tcl8.6/TclCmd/foreach.htm

Answer 3

Solution for Tcl < 8.6:
Given
array set count {Roger 15 Martin 18 Jemmy 16 Jon 12 Sara 12}
The way to get sorted outpus is
set L [list]
foreach {k v} [array get count] {
lappend L [list $k $v]
}
foreach e [lsort -index 1 -decreasing -integer $L] {
lassign $e k v
puts "$k $v"
}
Explanation:
Get a flat list of the interleaved keys and values using array get.
From it, produce a list of key/value pairs—a list of lists.
Given that list, sort it using the lsort command passing it
the -index 1 option which makes lsort interpret the elements of the
list it sorts as lists, and use their elements at index 1
(the 2nd position) for sorting.
To print out the elements of the sorted list, you need to extract the
key and the value back from each of them. The easiest way is to use
lassign but if you have Tcl < 8.5 you can use either the
foreach {k v} $e break trick or directly access the elements using
lindex $e 0 and lindex $e 1 to get the key and the value, respectively.