Tcl array sorting based on values - arrays

Question

I have an array with dynamic 'keys' and values associated with them.
I want to sort the array based on the value and want to be able to retrieve the 'keys' from the sorted array.
For example, say I have,
for {set i 0} {$i < [db_get_nrows $rs]} {incr i} {
set x [db_get_col $rs $i abc]
set ARRAY_A($x) [db_get_col $rs $i def]
}
So, my array would look like,
ARRAY_A(111) 10
ARRAY_A(222) 50
ARRAY_A(333) 20
Now, I want to sort this array based on it's values (with 50 first, then 20 and then 10). And then I'm interested in it's keys (222, 333 and 111) for further processing.
I couldn't find much in the internet for such arrays with dynamically generated keys.
Any help is much appreciated.
Thanks.

Answer 1

Well, I just wanted to first mention that you cannot sort arrays as they don't really have a fixed order, but are saved in a manner that makes it easier/faster for the interpreter to retrieve values.
If you want to get the keys of the array in the order of the values, you can maybe use something like that:
set key_value [lmap {key val} [array get ARRAY_A] {list $key $val}]
set key_value [lsort -index 1 -integer -decreasing $key_value]
The list key_value now holds key/value pairs of your array sorted by values in decreasing order. -index 1 indicates that the sort is sorting by the 2nd element of the sublist (Tcl has lists 0-based). -integer just instructs that we are sorting integers (and not using dictionary sort). You just need to get the keys from the list:
foreach n $key_value {
puts [lindex $n 0]
}
You can combine the above in a single loop if you want (I combined the loop and the second line, adding the first line will make it look a bit too much):
foreach n [lsort -index 1 -integer -decreasing $key_value] {
puts [lindex $n 0]
}

Answer 2

This part of the answer is mostly an addendum to Dinesh's answer and not complete in itself.
Once you have created a list containing the array elements sorted according to value, you can put it in a dictionary (which is another kind of associative list structure):
set d [lsort -stride 2 -integer -decreasing -index 1 $l]
The dictionary will preserve the order of insertion and allow easy access to e.g. the keys:
dict keys $d
# -> 222 333 111
eta
If you can't use lmap or -stride, you can still generate a dictionary like this:
set pairs {}
foreach {a b} [array get ARRAY_A] {
lappend pairs [list $a $b]
}
set DICT_A [concat {*}[lsort -index 1 -integer -decreasing $pairs]]
This method packs the elements into "pairs", sorts the packed list, and then unpacks it into a flat list to be usable as a dictionary as above.
Documentation: array, concat, dict, foreach, lappend, list, lsort, set

Answer 3

% set tcl_version
8.6
% array set n {111 10 222 50 333 20}
% parray n
n(111) = 10
n(222) = 50
n(333) = 20
% set l [array get n]
333 20 222 50 111 10
% lsort -stride 2 -integer -index 1 $l
111 10 333 20 222 50
% lsort -stride 2 -integer -decreasing -index 1 $l
222 50 333 20 111 10
%
You can get them as list with expected order and then try to apply your logic further.