Understanding start, 2>nul, cmd, and other symbols in a batch file - batch-file

Question

Following up from this topic on here, I'm trying to understand what's happening "behind the scenes" from a suggested answer. I don't understand what 2>nul or 1>nul is supposed to do. And I tried to decipher what the symbols in the start /b line is doing, but I am really clueless here. I need a step by step approach on that one if you don't mind.
What's happening in this part of the code?
2>nul del %lock%!nextProc!
%= Redirect the lock handle to the lock file. The CMD process will =%
%= maintain an exclusive lock on the lock file until the process ends. =%
start /b "" cmd /c %lockHandle%^>"%lock%!nextProc!" 2^>^&1 !cpu%%N! !cmd!
)
set "launch="
And this:
) 9>>"%lock%%%N"
) 2>nul
if %endCount% lss %startCount% (
1>nul 2>nul ping /n 2 ::1
goto :wait
)
2>nul del %lock%*
Copy of suggested code in full:
#echo off
setlocal enableDelayedExpansion
:: Display the output of each process if the /O option is used
:: else ignore the output of each process
if /i "%~1" equ "/O" (
set "lockHandle=1"
set "showOutput=1"
) else (
set "lockHandle=1^>nul 9"
set "showOutput="
)
:: Define the maximum number of parallel processes to run.
:: Each process number can optionally be assigned to a particular server
:: and/or cpu via psexec specs (untested).
set "maxProc=8"
:: Optional - Define CPU targets in terms of PSEXEC specs
:: (everything but the command)
::
:: If a cpu is not defined for a proc, then it will be run on the local machine.
:: I haven't tested this feature, but it seems like it should work.
::
:: set cpu1=psexec \\server1 ...
:: set cpu2=psexec \\server1 ...
:: set cpu3=psexec \\server2 ...
:: etc.
:: For this demo force all cpu specs to undefined (local machine)
for /l %%N in (1 1 %maxProc%) do set "cpu%%N="
:: Get a unique base lock name for this particular instantiation.
:: Incorporate a timestamp from WMIC if possible, but don't fail if
:: WMIC not available. Also incorporate a random number.
set "lock="
for /f "skip=1 delims=-+ " %%T in ('2^>nul wmic os get localdatetime') do (
set "lock=%%T"
goto :break
)
:break
set "lock=%temp%\lock%lock%_%random%_"
:: Initialize the counters
set /a "startCount=0, endCount=0"
:: Clear any existing end flags
for /l %%N in (1 1 %maxProc%) do set "endProc%%N="
:: Launch the commands in a loop
set launch=1
echo mem=1m 2m 3m 4m 6m 8m 12m 16m 24m 32m 48m 64m 96m 128m 192m 256m 384m 512m 768m 1024m
echo o=2 3 4 5 6 7 8 10 12 14 16 20 24 28 32
echo s=off 1m 2m 4m 8m 16m 32m 64m 128m 256m 512m 1g 2g 4g 8g 16g 32g 64g on
echo x=1 3 5 7 9
for %%x IN (9) DO for %%d IN (1024m 768m 512m 384m 256m 192m 128m 96m 64m 48m 32m 24m 16m 12m 8m 6m 4m 3m 2m 1m) DO (
set "cmd=7z.exe a teste.resultado\%%xx.ppmd.%%dd.%%ww.%%ss.7z .\teste.original\* -mx=%%x -m0=PPMd:mem=%%d:o=%%w -ms=%%s"
if !startCount! lss %maxProc% (
set /a "startCount+=1, nextProc=startCount"
) else (
call :wait
)
set cmd!nextProc!=!cmd!
if defined showOutput echo -------------------------------------------------------------------------------
echo !time! - proc!nextProc!: starting !cmd!
2>nul del %lock%!nextProc!
%= Redirect the lock handle to the lock file. The CMD process will =%
%= maintain an exclusive lock on the lock file until the process ends. =%
start /b "" cmd /c %lockHandle%^>"%lock%!nextProc!" 2^>^&1 !cpu%%N! !cmd!
)
set "launch="
:wait
:: Wait for procs to finish in a loop
:: If still launching then return as soon as a proc ends
:: else wait for all procs to finish
:: redirect stderr to null to suppress any error message if redirection
:: within the loop fails.
for /l %%N in (1 1 %startCount%) do (
%= Redirect an unused file handle to the lock file. If the process is =%
%= still running then redirection will fail and the IF body will not run =%
if not defined endProc%%N if exist "%lock%%%N" (
%= Made it inside the IF body so the process must have finished =%
if defined showOutput echo ===============================================================================
echo !time! - proc%%N: finished !cmd%%N!
if defined showOutput type "%lock%%%N"
if defined launch (
set nextProc=%%N
exit /b
)
set /a "endCount+=1, endProc%%N=1"
) 9>>"%lock%%%N"
) 2>nul
if %endCount% lss %startCount% (
1>nul 2>nul ping /n 2 ::1
goto :wait
)
2>nul del %lock%*
if defined showOutput echo ===============================================================================
echo Thats all folks!

Answer 1

The digit before a redirection symbol is the stream number to redirect.
The default stream is 1, when no number is present, so 1>... and >... are equivalent.
stream 1 is the standard input/output stream, 2 is the standard error stream.
A command can output to multiple streams and it's allowed to redirect each of them to a different destination.
So 2>nul and 1>nul simply said that the error output and the normal output will be redirected to nul. So nothing will be outputted.

Answer 2

My explanation:
1. 2>nul del %lock%!nextProc!
2. %= Redirect the lock handle to the lock file. The CMD process will =%
3. %= maintain an exclusive lock on the lock file until the process ends. =%
4. start /b "" cmd /c %lockHandle%^>"%lock%!nextProc!" 2^>^&1 !cpu%%N! !cmd!
5. )
6. set "launch="
Line 1: delete file and don't show errors. same as "del /Q". the exclamation
symbols require delayedexpansion be enabled to evaluate to anything. I would
have wrote it as: del /Q "%lock%!nextProc!"
Line 2: a really weird comment style. should just start each line with "::" instead
Line 3: same as line 2
Line 4: hard to tell without seeing rest of script. the %%N tells me that this section
is inside of a loop block. the ^ characters are necessary so that the start command
recognizes the special characters as part of the cmd command string. I don't think the start command was necessary
here IMHO. I bet that "start /B /wait" is the equivilant of "start /b "" cmd /c".
I would rewrite this script personally to make it easier to understand.
Also, see dostips.com
Also: 1>nul 2>nul ping /n 2 ::1 is the equivilant of "ping -n 2 -w 1000 127.1 >nul" but stupidly harder to understand.
Also: %~1 means to get the 1st arg %1 and trim quotes (if any)
I could go on and on but you should just research it yourself.

Answer 3

the 1>nul and 2>nul make it so no output is displayed.
the ^> in the start are so the > are passed to the start command, not interpreted. the cmd /c starts a new shell that executes the code after the /c and then exits.