Increment an array in assembly - arrays

Question

Coding an assembly program to be used as a dictionary. User gives in the word and the program checks whether that word is present or not. TASM, 16 bit. Program works perfect for the first two elements of the array but if I provide balls. , the 3rd element of the array, even though the next element of array is being chosen, (verified on emu8086, bx becomes 007ch,->refer to code<-), the repe cmpsb still finishes its check after a single try. works properly with the first two elements of the array. Here is my code
The program firsts checks the length and later the bits. Length check is ended when a period (.) is provided.
.model large
.data
arrayele db 00d ;to count if all elements of the array have been compared with
count db 00d ;length of input count
nl db 10d,13d,'$' ;newline
mne db "Not Equal$" ;message if not equal
me db "Equal$" ;message if equal
buf db 99,?,99 dup(?) ;buffer where the input will be saved
w0 db "hello$" ;word 0-5
w1 db "which$"
w2 db "balls$"
w3 db "table$"
w4 db "chair$"
w5 db "apples$"
words dw offset w0,offset w1 ;the array
dw offset w2,offset w3
dw offset w4,offset w5
.code
main proc
mov ax,#data
mov ds,ax
mov es,ax
;take user input
mov ah,0ah
mov dx,offset buf
int 21h
;print new line
mov ah,09h
mov dx,offset nl
int 21h
;load input to di
mov di,offset buf
add di,2
;//saving length to a variable
repeat:
mov al,[di]
inc count
cmp al,"."
je lenchck
inc di
jmp repeat
;//end saving
lenchck:
dec count ;as full stop (period) (.) is also included in the count
stringmatch1:
mov cx,0 ;reset register
mov arrayele,0 ;reset variable
stringmatch:
mov di,offset buf ;loading input to di
add di,2
;loading array element to si
mov bx,0
mov bl,byte ptr words
mov si,bx ;end loading array element to si
mov cl,count
repe cmpsb
je equal
inc arrayele
inc words ;next word in the array
mov bx,0 ;loading it
mov bl,byte ptr words
mov si,bx ;end loading
cmp arrayele,06d ;compare to check if all elements have been compared with
jg wrong
jmp stringmatch
wrong: ;load notequal message
mov dx,offset mne
jmp print
equal:
mov dx,offset me ;load equal message
print:
mov ah,09h ;print it
int 21h
mov ah,4ch ;exit the program
int 21h
main endp
end main

Answer 1

inc words ;next word in the array
No, sorry. You've incremented (what was) the offset of w0. You haven't moved to the next word in the array. You want something more like...
mov bx, offset words
top:
; get offset of a string
mov si, [bx]
; do your comparison
; start at beginning of input every time
mov di, offset buf + 2 ; don't need a separate operation
mov cl, count ; (are we sure ch is clear?)
repe cmpsb
je found
; no? get next offset in words array
add bx, 2
jmp top
In your loop where you look for the '.', what's going to happen if the pesky user doesn't enter a '.'? The second byte in your input buffer (buf + 1), after the interrupt returns, is the count actually entered. It includes the '.' (if there was one) and the Carriage Return (13 or 0Dh) that ended input. You may be able to use this information to rule out obviously incorrect input.